" Exercise 2.4

 Statistical Methods in Biology: Design and Analysis of Experiments and Regression
 by S.J. Welham, S.A. Gezan, S.J. Clark & A. Mead (2014)
 Chapman & Hall/CRC Press, Boca Raton, Florida. ISBN: 978-1-4398-0878-8
 Version 1, 16/09/2014 "

" Set working directory - change to location of your data file "
\SET [WORKINGDIRECTORY='d:/stats4biol/data/']

" Read data from working directory "
FILEREAD [NAME='CARBON.DAT'; IMETHOD=read] FGROUPS=no,yes,no

" Sample statistics "
DESCRIBE [SELECTION=mean,var; GROUPS=Field] DATA=Carbon

" Two-sample t-test & 95% CI directly "
TTEST [GROUPS=Field; CIPROBABILITY=0.95] Y1=Carbon

" Rest of file verifies t-test calculations "

" Get number of observations, mean and variance for each group "
TABULATE [PRINT=mean,variance,nobservations; CLASS=Field] Carbon; \
  MEAN=Tmean; VARIANCE=Tvar; NOBSERVATIONS=Tnobs
PRINT Tnobs; DEC=0
PRINT Tmean; DEC=1
PRINT Tvar; DEC=2

" Extract number of observations, means and variances "
CALCULATE n[1,2] = #Tnobs
CALCULATE Mean[1,2] = #Tmean
CALCULATE Variance[1,2] = #Tvar

" Calculate pooled estimate of variance "
CALCULATE PooledVar = ( ((n[1]-1)*Variance[1])+((n[2]-1)*Variance[2]) )/(n[1]+n[2]-2)
PRINT PooledVar; DEC=2

" Calculate t statistic "
CALCULATE SED = sqrt(PooledVar*((1/n[1])+(1/n[2])))
PRINT SED; DEC=2
CALCULATE t = (Mean[1]-Mean[2])/SED
PRINT t; DEC=3

" Get 5% critical value for two-sided test 
  = 97.5th quantile of t distribution with 10 df "
CALCULATE critical = EDT(0.975;n[1]+n[2]-2)
PRINT critical; DEC=3

" Get observed significance level for test 
  = proportion of t distribution with 10 df > abs(t) or < -abs(t) "
CALCULATE P = 2*CUT(ABS(t);n[1]+n[2]-2)
PRINT P; DEC=3

" Calculate confidence limits "
CALCULATE Lower = (Mean[1]-Mean[2]) - critical*SED
CALCULATE Upper = (Mean[1]-Mean[2]) + critical*SED
PRINT Lower,Upper; DEC=1

" End of File "