" Exercise 6.5

 Statistical Methods in Biology: Design and Analysis of Experiments and Regression
 by S.J. Welham, S.A. Gezan, S.J. Clark & A. Mead (2014)
 Chapman & Hall/CRC Press, Boca Raton, Florida. ISBN: 978-1-4398-0878-8
 Data from M. Torrance, Rothamsted Research
 Version 1, 20/08/2014 "

" Set working directory - change to location of your data file "
\SET [WORKINGDIRECTORY='d:/stats4biol/data/']

" Read data from working directory "
FILEREAD [NAME='PARASITOIDS.DAT'; IMETHOD=read] FGROUPS=no,yes,no

" Tabulate treatment sample means and variances "
TABULATE [CLASSIFICATION=Treatment; PRINT=means,variances] DATA=OpticalDensity

" Bartlett's test "
VHOMOGENEITY [PRINT=test,variances; GROUPS=Treatment] DATA=OpticalDensity

" One-way ANOVA of full, untransformed data set "
TREATMENTSTRUCTURE Treatment
ANOVA [FPROBABILITY=yes] Y=OpticalDensity

" Residual plots "
APLOT [RMETHOD=standardized] METHOD=fittedvalues,normal,histogram,absresidual

" Remove positive control treatment (label 0) "
SUBSET [CONDITION=Treatment.NE.2; SETLEVELS=yes] OLDVECTOR=DParasitoid,Treatment,OpticalDensity

" Transform response to log scale "
CALCULATE LogOpt=LOG10(OpticalDensity)

" One-way ANOVA excluding Day0 treatment "
TREATMENTSTRUCTURE Treatment
ANOVA [FPROBABILITY=yes] Y=LogOpt
APLOT [RMETHOD=standardized] METHOD=fittedvalues,normal,histogram,absresidual

" One-way ANOVA of log-transform excluding Day0 treatment "
TREATMENTSTRUCTURE Treatment
ANOVA [FPROBABILITY=yes; PSE=differences,means,lsd] Y=LogOpt
APLOT [RMETHOD=standardized] METHOD=fittedvalues,normal,histogram,absresidual

" Remove negative control treatment (label Control) "
SUBSET [CONDITION=Treatment.NE.1; SETLEVELS=yes] \
  OLDVECTOR=DParasitoid,Treatment,OpticalDensity,LogOpt

" One-way ANOVA on log-transform excluding Day0 and Control treatment "
TREATMENTSTRUCTURE Treatment
ANOVA [FPROBABILITY=yes; PSE=differences,means,lsd] Y=LogOpt
APLOT [RMETHOD=standardized] METHOD=fittedvalues,normal,histogram,absresidual

" Extract treatment means and print on back-transformed scale "
AKEEP TERMS=Treatment; MEANS=means; SEMEANS=sem
PRINT STRUCTURE=10**means

" Plot treatment means (log scale) with LSD "
AGRAPH [METHOD=means; PSE=lsd] X=Treatment

" End of File "